Резервное копирование и восстановление базы данных 1С: полная инструкция | IT-компания Виант

Настройка и техническая поддержка 1C

Подробнее

Настройка автоматического резервного копирования

Для автоматизации процесса резервного копирования необходимо настроить регламентное задание через SQL Server Agent.

Создание плана обслуживания

1. В SQL Server Management Studio разверните раздел Управление;
2. Щелкните правой кнопкой мыши Планы обслуживания и выберите Создать план обслуживания;
3. Задайте имя плана и настройте расписание выполнения;
4. Из панели инструментов перетащите задачу Резервное копирование базы данных в область конструктора;
5. Настройте параметры задачи: выберите базы данных, тип резервного копирования, место назначения и параметры проверки;
6. Сохраните план обслуживания.

Создание задания через SQL Server Agent

Альтернативный способ — создание задания напрямую:

1. Откройте SQL Server Management Studio и подключитесь к серверу
2. Разверните SQL Server Agent → щелкните правой кнопкой Jobs → выберите New Job
3. На вкладке General укажите имя задания, например, Full Backup [ИМЯ_БАЗЫ]
4. На вкладке Steps нажмите New и создайте шаг:
   • Step name: Create Full Backup
   • Type: Transact-SQL script (T-SQL)
   • Database: master
   • Command: вставьте T-SQL команду создания резервной копии
5. На вкладке Schedules настройте расписание выполнения
6. На вкладке Notifications настройте уведомления об успешном или неудачном выполнении
7. Нажмите ОК для сохранения задания

Рекомендуется создать несколько заданий для разных типов резервного копирования в соответствии с рекомендуемой стратегией.

Проверка целостности резервных копий

Создание резервной копии — это только половина задачи. Необходимо регулярно проверять возможность восстановления из созданных копий.

Быстрая проверка целостности файла

Команда RESTORE VERIFYONLY проверяет полноту резервной копии и возможность её считывания:

RESTORE VERIFYONLY 
FROM DISK = N'D:\SQL\Backup\ИМЯ_БАЗЫ.bak'
WITH CHECKSUM
GO

Эта команда не восстанавливает базу данных, а только проверяет структурную целостность файла резервной копии.

Проверка целостности базы данных перед резервным копированием

Рекомендуется проверять целостность базы данных перед созданием резервной копии:

-- Проверка целостности базы данных
DBCC CHECKDB ('ИМЯ_БАЗЫ') WITH NO_INFOMSGS

-- Если проверка прошла успешно, создаем резервную копию
IF @@ERROR = 0
BEGIN
    BACKUP DATABASE [ИМЯ_БАЗЫ]
    TO DISK = N'D:\SQL\Backup\ИМЯ_БАЗЫ.bak'

    WITH CHECKSUM, COMPRESSION, INIT
    PRINT 'Резервное копирование выполнено успешно'
END
ELSE
BEGIN
    RAISERROR('Обнаружены ошибки целостности базы данных', 16, 1)
END
GO

Автоматическая проверка резервных копий по расписанию

Скрипт для проверки последней созданной резервной копии:

DECLARE @BackupPath NVARCHAR(500)
DECLARE @DatabaseName NVARCHAR(128) = 'ИМЯ_БАЗЫ'
DECLARE @BackupFile NVARCHAR(500)

-- Формирование пути к файлу резервной копии
SET @BackupPath = 'D:\SQL\Backup\'
SET @BackupFile = @BackupPath + @DatabaseName + '_' + 
    CONVERT(VARCHAR(8), GETDATE(), 112) + '.bak'

-- Проверка целостности резервной копии
BEGIN TRY
    RESTORE VERIFYONLY 
    FROM DISK = @BackupFile
    WITH CHECKSUM
    
    PRINT 'Проверка резервной копии успешно завершена: ' + @BackupFile
END TRY
BEGIN CATCH
    PRINT 'ОШИБКА при проверке резервной копии: ' + ERROR_MESSAGE()
    RAISERROR('Резервная копия повреждена или недоступна', 16, 1)
END CATCH
GO

Расширенный скрипт проверки всех резервных копий в папке

Для проверки всех файлов резервных копий в указанной папке используйте следующий скрипт:

DECLARE @BackupPath NVARCHAR(500) = 'D:\SQL\Backup\'
DECLARE @Command NVARCHAR(4000)
DECLARE @BackupFile NVARCHAR(500)

-- Создание временной таблицы для списка файлов
CREATE TABLE #BackupFiles (
    FileName NVARCHAR(500)
)

-- Получение списка файлов резервных копий
SET @Command = 'DIR "' + @BackupPath + '*.bak" /B'
INSERT INTO #BackupFiles
EXEC xp_cmdshell @Command

-- Удаление NULL значений
DELETE FROM #BackupFiles WHERE FileName IS NULL

-- Курсор для проверки каждого файла
DECLARE backup_cursor CURSOR FOR
SELECT FileName FROM #BackupFiles

OPEN backup_cursor
FETCH NEXT FROM backup_cursor INTO @BackupFile

WHILE @@FETCH_STATUS = 0
BEGIN
    SET @Command = @BackupPath + @BackupFile
    
    BEGIN TRY
        PRINT 'Проверка файла: ' + @BackupFile
        
        RESTORE VERIFYONLY 
        FROM DISK = @Command
        WITH CHECKSUM
        
        PRINT 'OK: ' + @BackupFile
    END TRY
    BEGIN CATCH
        PRINT 'ОШИБКА в файле ' + @BackupFile + ': ' + ERROR_MESSAGE()
    END CATCH
    
    FETCH NEXT FROM backup_cursor INTO @BackupFile
END

CLOSE backup_cursor
DEALLOCATE backup_cursor

DROP TABLE #BackupFiles
GO

Этот скрипт можно добавить как отдельное задание SQL Server Agent, которое будет запускаться после создания резервных копий.

Восстановление базы данных из резервной копии

При возникновении проблемы с базой данных, требующей восстановления, необходимо сначала сделать резервную копию журналов транзакций без его обрезки (если это возможно).

Восстановление через графический интерфейс

1. В SQL Server Management Studio щелкните правой кнопкой мыши по базе данных
2. Выберите Задачи → Восстановить → База данных
3. В окне восстановления выберите источник восстановления (устройство или файл)
4. Укажите путь к файлу резервной копии
5. Выберите необходимые резервные копии для восстановления (полная, разностная, журналы)
6. На вкладке Параметры настройте необходимые опции восстановления
7. Нажмите ОК для начала процесса восстановления

Восстановление через T-SQL

Для восстановления полной резервной копии используйте команду:

RESTORE DATABASE [ИМЯ_БАЗЫ]
FROM DISK = N'C:\Backup\SQLTestDB.bak'
WITH FILE = 1, NOUNLOAD, STATS = 5
GO

Последовательное восстановление нескольких резервных копий

Для восстановления полной, разностной копии и журналов транзакций:

-- Восстановление полной резервной копии с опцией NORECOVERY
RESTORE DATABASE [ИМЯ_БАЗЫ]
FROM DISK = N'D:\Backup\VIANT_AC_Full.bak'
WITH NORECOVERY, REPLACE
GO

-- Восстановление разностной резервной копии с опцией NORECOVERY
RESTORE DATABASE [ИМЯ_БАЗЫ]
FROM DISK = N'D:\Backup\VIANT_AC_Diff.bak'
WITH NORECOVERY
GO

-- Восстановление журнала транзакций с опцией RECOVERY (последний шаг)
RESTORE LOG [ИМЯ_БАЗЫ]
FROM DISK = N'D:\Backup\VIANT_AC_Log.trn'
WITH RECOVERY
GO

Опция NORECOVERY оставляет базу данных в состоянии восстановления, что позволяет применить дополнительные резервные копии. Последняя операция восстановления должна использовать опцию RECOVERY для завершения процесса и перевода базы данных в рабочее состояние.

Рекомендации по хранению резервных копий

Для обеспечения максимальной надежности системы резервного копирования следуйте этим рекомендациям:

• Храните резервные копии на отдельном физическом диске или сетевом хранилище, отличном от диска с рабочей базой данных;
• Используйте несколько независимых мест хранения резервных копий;
• Регулярно проверяйте целостность и возможность восстановления из резервных копий;
• Документируйте процедуры создания и восстановления резервных копий;
• Настройте автоматические уведомления о результатах выполнения заданий резервного копирования;
• Определите политику хранения резервных копий в соответствии с требованиями бизнеса;
• Обеспечьте достаточное количество свободного места на диске для хранения резервных копий;
• Не храните резервные копии на том же диске, где установлена операционная система.

Проверяйте себя и избегайте создания резервных копий без использования параметра CHECKSUM.

Заключение

Правильная настройка резервного копирования базы данных 1С на SQL Server требует понимания моделей восстановления, типов резервных копий и оптимальной стратегии их создания. Регулярное резервное копирование в сочетании с автоматической проверкой целостности и периодическим тестированием процедуры восстановления обеспечивает надежную защиту корпоративных данных.